# Maintainer: IovAnto <iovine.antonio44@gmail.com>
pkgname=dns-switcher-git
pkgver=r1.0000000
pkgrel=1
pkgdesc="TUI application for real-time DNS switching on Linux (git version)"
arch=('x86_64')
url="https://github.com/IovAnto/dns-switcher"
license=('MIT')
depends=('networkmanager' 'polkit')
makedepends=('rust' 'cargo' 'git')
provides=('dns-switcher')
conflicts=('dns-switcher')
source=("$pkgname::git+https://github.com/IovAnto/dns-switcher.git")
sha256sums=('SKIP')

pkgver() {
    cd "$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "$pkgname"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo build --release
}

check() {
    cd "$pkgname"
    export RUSTUP_TOOLCHAIN=stable
    cargo test --release
}

package() {
    cd "$pkgname"
    install -Dm755 "target/release/dns-switcher" "$pkgdir/usr/bin/dns-switcher"
    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/${pkgname%-git}/LICENSE"
    install -Dm644 "README.md" "$pkgdir/usr/share/doc/${pkgname%-git}/README.md"
}
