# Maintainer: Jack Danger <jack@jackdanger.com>
pkgname=tdorr
pkgver=0.1.0
pkgrel=1
pkgdesc="GPU-accelerated media transcoding that I could figure out"
arch=('x86_64' 'aarch64')
url="https://github.com/JackDanger/tdorr"
license=('MIT')
depends=('ffmpeg')
makedepends=('cargo')
optdepends=('nvidia-utils: for NVIDIA NVENC encoding'
            'intel-media-driver: for Intel VAAPI encoding'
            'isomage: for .iso/.img disc image support')
source=("$pkgname-$pkgver.tar.gz::https://github.com/JackDanger/tdorr/archive/v$pkgver.tar.gz")
sha256sums=('SKIP')

prepare() {
  cd "$pkgname-$pkgver"
  export RUSTUP_TOOLCHAIN=stable
  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
  cd "$pkgname-$pkgver"
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  cargo build --frozen --release
}

package() {
  cd "$pkgname-$pkgver"
  install -Dm755 "target/release/tdorr" "$pkgdir/usr/bin/tdorr"
  install -Dm644 "config.yaml" "$pkgdir/etc/tdorr/config.yaml"
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
